!#!Chapter Template
$ System-dimensions
#define L1 = 5.00 $ length of girder, left side
#define L2 = 5.00 $ length of girder, right side
#define HSt = 6.00 $ height of column
$ cross sections
#define bSt = 0.20 $ lenght/width of quadratic column
#define bR = 0.20 $ width of girder
#define hRu = 0.60 $ height of girder on the sides
#define hRo = 1.00 $ height of girder in the middle
$data for design
#define Beton = 25 $ type of concrete
#define d1 = 50 $ offset of top/ bottom reinforcement
$loading
#define q0 = 50.00 $ line load
$variables for calculation
#define Dh = (($(hRo)-$(hRu))/2)
+prog template urs:1
head
Concrete frame with exzentric girder
This example includes the calculation and design
of a steal frame with a line load.
Dimensions, loading and design data may be changed.
System dimensions
length of girder, left side L1 = $(L1) m
length of girder, right side L2 = $(L2) m
height of column HSt = $(HSt) m
Cross sections
Lenght/width of quadratic column bSt = $(bSt) mm
Width of girder bR = $(bR) mm
Height of girder on the sides hRu = $(hRu) mm
height of girder in the middle hRo = $(hRo) mm
Data for design
Material concrete = C $(Beton)
Offset of reinforcement d1 = $(d1) mm
Loading
Line load q0 = $(q0) kN/m2
ycm 10 text "System"
gnt 1 sc 100 xmin -1 ymin -2.0
$ headline
gtxi h 0.4
gtxt x 0 y 2.0+$(HSt) text "System:"
$ girder
gpli widt 3
gpl x1 0.00 $(HSt) x2 $(L1)+$(L2) $(HSt) x3 $(L1)+$(L2) $(HSt)+$(hRu) $$
x4 $(L1) $(HSt)+$(hRo) x5 0.00 $(HSt)+$(hRu) x6 0.00 $(HSt)
$ midle line of girder
gpl x1 $(L1) $(HSt) x2 $(L1) $(HSt)+$(hRo)
$ column left
gpl x1 -$(bSt)/2 y1 0 x2 $(bSt)/2 y2 0 $$
x3 $(bSt)/2 y3 $(HSt)-0.57 x4 -$(bSt)/2 y4 $(HSt)-0.57 $$
x5 -$(bSt)/2 y5 0
$ column right
gpl x1 $(L1)+$(L2)-$(bSt)/2 y1 0 x2 $(L1)+$(L2)+$(bSt)/2 y2 0 $$
x3 $(L1)+$(L2)+$(bSt)/2 y3 $(HSt)-0.57 x4 $(L1)+$(L2)-$(bSt)/2 y4 $(HSt)-0.57 $$
x5 $(L1)+$(L2)-$(bSt)/2 y5 0
$ symbols for hinges
ggdp type circ x1 0.00 y1 $(HSt)-0.3 x2 0.3 y2 $(HSt)-0.3
ggdp type circ x1 $(L1)+$(L2) y1 $(HSt)-0.3 x2 $(L1)+$(L2)+0.3 y2 $(HSt)-0.3
$ symbols for constraints
let#dx 0.5
let#dh 0.3
gfai styl hatc type 5
gfa x1 0.00-#dx 0.00 x2 0.00+#dx 0.00 x3 0.00+#dx 0.00-#dh x4 0.00-#dx 0.00-#dh
gpl x1 0.00-#dx 0.00 x2 0.00+#dx 0.00
let#D $(L1)+$(L2)
gfai styl hatc type 5
gfa x1 #D-#dx 0.00 x2 #D+#dx 0.00 x3 #D+#dx 0-#dh x4 #D-#dx 0-#dh
gpl x1 #D-#dx 0.00 x2 #D+#dx 0.00
$ dimensioning
gtxi h 0.3
gpli widt 1
gpli scat 1
gsca x1 0 -1.0 x2 $(L1) -1.0 text "L1 =" nd 2
gsca x1 $(L1) -1.0 x2 $(L1)+$(L2) -1.0 text "L2 =" nd 2
gsca x1 0 -1.8 x2 $(L1)+$(L2) -1.8 text "L =" nd 2
gsca x1 $(L1)+$(L2)+1.8 0.00 x2 $(L1)+$(L2)+1.8 $(HSt) text "HSt" nd 2
gsca x1 $(L1)+$(L2)+1.8 $(HSt) x2 $(L1)+$(L2)+1.8 $(HSt)+$(hRu) text "hRu" nd 2
gsca x1 $(L1)+1.2 $(HSt) x2 $(L1)+1.2 $(HSt)+$(hRo) text "hRo" nd 2
gsca x1 $(L1)+$(L2)-$(bSt)/2 $(HSt)+$(hRo)+0.5 $$
x2 $(L1)+$(L2)+$(bSt)/2 $(HSt)+$(hRo)+0.5 text "bSt" nd 2
ycm 6 text "Cross sections"
gnt 1 sc 50 xmin -1 ymin -0.6
$ headline
gtxi h 0.4
gtxt x 0 y 1.0+$(hRo) text "Cross sections:"
gtxi h 0.35
gtxt x 0 y 0.4+$(hRu) text " Girder on the sides:"
gfai styl bhat type 26
let#dx 0.00
gfa x1 0.00+#dx y1 0.00 x2 $(bR)+#dx y2 0.00 x3 $(bR)+#dx y3 $(hRu) $$
x4 0.00+#dx y4 $(hRu) x5 0.00+#dx y5 0.00
gpli scat 1
gsca x1 0+#dx -0.5 x2 $(bR)+#dx -0.5 nd 2
gsca x1 0.5+#dx+$(bR) 0.0 x2 0.5+#dx+$(bR) $(hRu) nd 2
let#dx 2.00
gtxt x 0+#dx y 0.4+$(hRo) text "Girder in the middle:"
gfa x1 0.00+#dx y1 0.00 x2 $(bR)+#dx y2 0.00 x3 $(bR)+#dx y3 $(hRo) $$
x4 0.00+#dx y4 $(hRo) x5 0.00+#dx y5 0.00
gsca x1 0+#dx -0.5 x2 $(bR)+#dx -0.5 nd 2
gsca x1 0.5+#dx+$(bR) 0.0 x2 0.5+#dx+$(bR) $(hRo) nd 2
let#dx 4.00
gtxt x 0+#dx y 0.4+$(bSt) text "column cross section:"
gfa x1 0.00+#dx y1 0.00 x2 $(bSt)+#dx y2 0.00 x3 $(bSt)+#dx y3 $(bSt) $$
x4 0.00+#dx y4 $(bSt) x5 0.00+#dx y5 0.00
gsca x1 0+#dx -0.5 x2 $(bSt)+#dx -0.5 nd 2
gsca x1 0.5+#dx+$(bSt) 0.0 x2 0.5+#dx+$(bSt) $(bSt) nd 2
ycm 12 text "System with loading"
$ frame
gnt 1 sc 100 xmin -1.5 ymin -2.0 $ wxmi 0 0 15 15
let#d $(HSt)
gpli widt 5
gpl x1 0.00 0.00 x2 0.00 $(HSt) x3 $(L1) y3 $(HSt) $$
x4 $(L1)+$(L2) $(HSt) x5 $(L1)+$(L2) 0.00
$ loading
gpli widt 2
ggdp type vec1 $$
x1 0 y1 1+#d $$
x2 0 y2 -0.8 $$
x3 $(L1)+$(L2) y3 1+#d $$
x4 0 y4 -0.8
$ dimensioning
gtxi h 0.3
gpli scat 1
gsca x1 0 -1.0 x2 $(L1) -1.0 text "L1 =" nd 2
gsca x1 $(L1) -1.0 x2 $(L1)+$(L2) -1.0 text "L2 =" nd 2
gsca x1 0 -1.8 x2 $(L1)+$(L2) -1.8 text "L =" nd 2
gsca x1 $(L1)+$(L2)+1.8 0.00 x2 $(L1)+$(L2)+1.8 $(HSt) text "H =" nd 2
$ heading
gtxi h 0.4
gtxt x 0 y 2.5+#d text "System with loading: $(q0) kN/m"
$ symbols for hinges
ggdp type circ x1 0.00 y1 $(HSt) x2 0.15 y2 $(HSt)
ggdp type circ x1 $(L1)+$(L2) y1 $(HSt) x2 $(L1)+$(L2)+0.15 y2 $(HSt)
$ symbols for constraints
let#dx 0.5
let#dh 0.3
gfai styl hatc type 5
gfa x1 0.00-#dx 0.00 x2 0.00+#dx 0.00 x3 0.00+#dx 0.00-#dh x4 0.00-#dx 0.00-#dh
gpl x1 0.00-#dx 0.00 x2 0.00+#dx 0.00
let#D $(L1)+$(L2)
gfai styl hatc type 5
gfa x1 #D-#dx 0.00 x2 #D+#dx 0.00 x3 #D+#dx 0-#dh x4 #D-#dx 0-#dh
gpl x1 #D-#dx 0.00 x2 #D+#dx 0.00
end
!#!Chapter System definition
+prog aqua urs:2
head Cross section with reference point
norm EN 1992-2004
echo full
conc 1 C $(Beton)
stee 2 S 500A
srec 1 h $(bSt)*1000 b $(bSt)*1000 so $(d1) rtyp 'CORN' ref c titl "Column cross section"
srec 2 h $(hRu)*1000 b $(bR)*1000 so $(d1) rtyp 'ASYM' ref lm titl "Girder on the sides" $ reference lower middle
srec 3 h $(hRo)*1000 b $(bR)*1000 so $(d1) rtyp 'ASYM' ref lm titl "Girder in the middle" $ reference lower middle
end
+prog sofimsha urs:3
head Interpolation of cross sections for a haunched, exzentric beam
head Training example with a simple concrete frame
syst fram gdir YY
node 1 0.00 0.00 fix f
node 2 0.00 -$(HSt)
node 3 $(L1) -$(HSt)
node 4 $(L1)+$(L2) -$(HSt)
node 5 $(L1)+$(L2) 0.00 fix f
beam 1 na 1 ne 2 ncs 1 div 2 ehin my
beam 2 na 2 ne 3 ncs 2.3 np -1 div 4 $ haunched girder left
beam 3 na 3 ne 4 ncs 3.2 np -1 div 4 $ haunched girder right
beam 4 na 4 ne 5 ncs 1 div 2 ahin my
end
+prog aqua urs:4 $ Interpolation of in-between cross sections of haunched beams
inte 0
end
!#!Chapter Loading
+prog sofiload urs:5 $ Single loadcases
head loading
act G
lc 1 dly 1 titl "self weight"
act Q
lc 2 titl "variable load"
beam from 2 to 3 inc 1 type pyp $(q0)
end
+prog sofiload urs:6 $ Loadcase combination
head self defined loadcase combination
lc 1001 type (D) titl '1.35*g+1.5*q'
copy 1 1.35
copy 2 1.5
end
!#!Chapter Calculation and desing
+prog ase urs:7 $ Calculation of strsess resultant
syst prob line
lc 1001
end
+prog aqb urs:8 $ Design
head design
lc 1001
rein mod sect rmod save lcr 1001
desi stat ulti
end